ホーム
2009/07/24
TRIO DM6 を持っているのですが、自作の研究をしてみました。
ＨＡＭジャーナル79のデップメーターの全て
に解説されているものを作ってみました。
回路図です。
記事では1-100ＭＨｚとなっていますが、200ＭＨｚ位まで使えそうです。
1コイルで4倍の周波数まで使えます。
200-50,50-12,12-3,3-0.8 4個のコイルで全バンド 200ＭＨｚ以上は別回路で作成
ＴＲは手持ちを使っています。
周波数表示はカウンターを組み込むことにしました。
使用した7セグが4桁パラ接続のため普通の接続方式にしました。
発信回路が9Ｖ動作のため7805を使って電圧9-5Ｖに変更
ＪＷＣＡＤで基板設計
30㎜*34㎜の大きさです。
ＰＩＣでは60ＭＨｚ までしか使えませんからﾌﾟﾘｽｹｰﾗｰを付けてみました。
ヤオフクで入手したＢＧ3013です。
上は450ＭＨｚをカウント中です。ところがこのＩＣ感度が低いです。規格では0.2Ｖですが、入力100オームで終端してＳＧ出力1Ｖでカウントしています。
問題発生 低いほうは60ＭＨｚが限界です。低域は何が制限しているのでしょうか？等価回路が無いので？？
ＩＣ内部にコンデンサーは無いと思うのですが！
基板裏のﾌﾟﾘｽｹｰﾗｰＢＧ3013です。
1ＭＨｚから200ＭＨｚまで切替なしでカウントする方法を考えなくては
1-200ＭＨｚまで使える分周ＩＣ無いかな！！設計変更です。
74ＡＳＬ4040 200ＮＨｚまで使えるようなので分周してみようかと！
;４桁 A_LED 09/6/16 JA0BAS FCOUNT 4MHZ ＡＳＭ ＬＩＳＴ ｂｙ ＪＡ０ＢＡＳ
;CALLは2スタック,512ワード,リセットベクタ1FF
;T0IF,SUBLWが無い バンク切替不要 TRISのアドレスなし
;PORTがINの場合は変更できない
;1/128 プリスケーラー用
LIST P=16F54
INCLUDE "P16F5X.INC"
__CONFIG _CP_OFF & _WDT_OFF & _HS_OSC
ERRORLEVEL -220 ; SUPPRESS MESSAGE 302 FROM LIST FILE
TIMA EQU 07H ;*256
TIM0 EQU 08H ;PSAﾉ値LO(TIM)｡
TIM1 EQU 09H ;TMR0ﾉ値
TIM2 EQU 0AH ;TOIFﾆﾖﾘINCｼﾀ値
TIM3 EQU 0BH ;TIM(2)ﾉOVERﾌﾛｰﾆﾖﾘINCｼﾀ値
TIM_M EQU 0CH ; 一時余ﾘ格納場所(SUBﾙｰﾁﾝﾃﾞ使用)
D EQU 0DH
COUNT EQU 0EH
OVERF EQU 0FH
DEC0 EQU 10H ;1GHZ
DEC1 EQU 11H ;100MHZ ;9桁7SEG ﾃﾞｰﾀ
DEC2 EQU 12H ;10MHZ
DEC3 EQU 13H ;1MHZ
DEC4 EQU 14H ;100KHZ
DEC5 EQU 15H ;10KHZ
DEC6 EQU 16H ;1KHZ
DEC7 EQU 17H ;100HZ
DEC8 EQU 18H ;10HZ
DEC9 EQU 19H ;1HZ
DEC EQU 1AH
WAIT_A EQU 1BH
WAIT_B EQU 1CH
WAIT_C EQU 1DH
K_POS EQU 1EH ;桁位置
CN EQU 1FH
ORG 1FFH
GOTO INIT_
ORG 0H
TABLE ;PCL+W=JMP,ﾃﾞｰﾀｦ持ｯﾃRETｽﾙ
ANDLW B'00001111' ;下位4ﾋﾞｯﾄ有効
ADDWF PCL,F
; ADBECGF
RETLW B'10000010' ;0
RETLW B'11101011' ;1
RETLW B'10000101' ;2
RETLW B'10001001' ;3 A
RETLW B'11101000' ;4 F B
RETLW B'10011000' ;5 G
RETLW B'10010000' ;6 E C
RETLW B'10101011' ;7 D
RETLW B'10000000' ;8
RETLW B'10001000' ;9
RETLW B'10100000' ;A
RETLW B'11010000' ;B
RETLW B'10010110' ;C
RETLW B'11000001' ;D
RETLW B'10010100' ;E
RETLW B'10110100' ;F
INIT_
MOVLW B'00100111' ;PRESCALER 1/256 SET;立上ｶｳﾝﾄ
OPTION
MOVLW B'11110111'
MOVWF PORTA
MOVLW B'11111111'
MOVWF PORTB
MOVLW B'00000000'
TRIS PORTB
CMAIN
MOVLW B'11111000'
TRIS PORTA ;PORTA3ｦINPUT MODE=HIGH IMPEDANCE/TMR0ﾉ開始
CLRWDT ;250 MS ｶｳﾝﾄﾉ始点 ++++++++++++++++++++++
CLRF TMR0 ;ｶｳﾝﾀTMR0ｦｸﾘｱ
MOVLW D'13' ;時間調整3
MOVWF WAIT_A ;
C1 DECFSZ WAIT_A,F
GOTO C1
MOVLW D'79' ;時間調整1
MOVWF WAIT_B
DISPLAY
MOVLW 13H ;
MOVWF FSR ;ｱﾄﾞﾚｽｦｾｯﾄ
MOVF INDF,W ;FSR番地ｶﾗ表示DATA取得
CALL TABLE ;7SEG DATA ﾆ変換
MOVWF PORTB ;7SEG DATA ﾆ出力
BSF PORTB,7
BCF PORTA,0
CALL DELAY
DECF FSR,F
MOVF INDF,W ;FSR番地ｶﾗ表示DATA取得
CALL TABLE ;7SEG DATA ﾆ変換
MOVWF PORTB ;7SEG DATA ﾆ出力
BSF PORTA,0
BCF PORTA,1
CALL DELAY
DECF FSR,F
MOVF INDF,W ;FSR番地ｶﾗ表示DATA取得
CALL TABLE ;7SEG DATA ﾆ変換
MOVWF PORTB ;7SEG DATA ﾆ出力
BSF PORTA,1
BCF PORTA,2
CALL DELAY
DECF FSR,F
MOVF INDF,W ;FSR番地ｶﾗ表示DATA取得
CALL TABLE ;7SEG DATA ﾆ変換
MOVWF PORTB ;7SEG DATA ﾆ出力
BSF PORTA,2
BCF PORTB,7
CALL DELAY
DECFSZ WAIT_B,F
GOTO DISPLAY
MOVLW B'11110000'
TRIS PORTA ;PORTA.3ｦOUT TMR0ﾉ停止 250MSｶｳﾝﾄﾉ終点 ++++++++
NOP ;WAIT
NOP
MOVF TMR0,W
MOVWF TIM1
TOGGLE ;GOTO X4
BSF PORTA,3 ;PORT PORTA4ﾉﾄｸﾞﾙ ﾌﾟﾘｽｹｰﾗﾉ読出
NOP
BCF PORTA,3
NOP
DECF TIM0,F
MOVF TMR0,W
SUBWF TIM1,W ;TIM1-TMR0=0ﾃﾞｱﾚﾊﾞ Z=1
BTFSC STATUS,Z
GOTO TOGGLE
X4
BCF STATUS,C ;*2 250MS 計測値ｦ2倍ｽﾙ
RLF TIM0,F
RLF TIM1,F
RLF TIM2,F
RLF TIM3,F
HD_C ;16進->10進変換
MOVLW H'19' ;格納場所開始アドレス
MOVWF FSR ;格納場所初期値
MOVLW D'10' ;回数SET 10回繰返
MOVWF COUNT
DEVIDE ;÷10ｻﾌﾞﾙｰﾁﾝ
MOVLW D'40'
MOVWF CN ;40ﾋﾞｯﾄｸﾘ返ｼ
CLRF TIM_M
DEVIDE0
BCF STATUS,C
RLF TIMA,F
RLF TIM0,F
RLF TIM1,F
RLF TIM2,F
RLF TIM3,F
RLF TIM_M,F
MOVLW B'11110110' ;246
ADDWF TIM_M,0
BTFSC STATUS,C
MOVWF TIM_M
BTFSC STATUS,C
INCF TIMA,F
DECFSZ CN,F
GOTO DEVIDE0
DECF FSR,F
MOVF TIM_M,W
MOVWF INDF ; 余ﾘ
DECFSZ COUNT,F
GOTO DEVIDE
CLRF TIMA ;変数ｸﾘﾔ 終了処理
CLRF TIM0
CLRF TIM1
CLRF TIM2
CLRF TIM3
GOTO CMAIN ;NEXT COUNT
DELAY ;STEP数を揃える事
MOVLW D'253' ;時間調整2
MOVWF WAIT_C ;
D1 DECFSZ WAIT_C,F
GOTO D1
BTFSC OVERF,1 ;前回の状態確認0ｽｷｯﾌﾟ
GOTO D2 ;前回１JANP
BTFSC TMR0,7 ;TMRは1?0ｽｷｯﾌﾟ
BSF OVERF,1 ;ｵｰﾊﾞｰしない
NOP ;STEP 調整
NOP ;STEP 調整
GOTO D3 ;ｵｰﾊﾞｰJAMP
D2 BTFSC TMR0,7 ;0になったか
GOTO D4 ;STEP 調整
BCF OVERF,1 ;ﾌﾗｸﾞSET
BSF OVERF,2 ;TOIFｵｰﾊﾞｰﾌﾗｸﾞSET
NOP ;STEP 調整
D3 BCF STATUS,C ;ｷｬﾘｰｸﾘﾔ
BTFSC OVERF,2 ;TOIFｵｰﾊﾞｰﾌﾛｰﾁｪｯｸ
INCF TIM2,F ;TIM1 ｵｰﾊﾞｰﾌﾛｰ
BTFSC STATUS,C
INCF TIM3,F ;TIM2 ｵｰﾊﾞｰﾌﾛｰ
BCF OVERF,2 ;TOIFﾌﾗｸﾞｸﾘﾔ
RETLW 0
D4 GOTO D3 ;STEP 調整
END
自動レンジ切替とか、0非表示とか色々出来ますが、省略
09/08/10
近くのパーツ屋さんで 74ＶＨＣ4040 が手に入ったので プリスケーラーで使ってみました。
当初規格を勘違いしていました。
入力Ｈレベルが 0.7Ｖ と思ったのですが、組み立てると動作がおかしく良く規格表を眺めたところ ＶＣＣ * 0.7 でした。
つまり 5 * 0.7 ＝3.5Ｖです。
Ｌは ＶＣＣ * 0.3＝1.5Ｖ ですので1.5Ｖから3.5Ｖまで振ってやる必要があります。
規格では210ＭＨｚでしたが
、私のＳＳＧ最高出力の240ＭＨｚでもきちんとカウントしています。
低い周波数では10ｍＶ でカウントします。 高くなるにしたがって感度悪くなり240ＭＨｚで1Ｖ
これで100ＫＨｚから240ＭＨｚまで切替なしで表示するデップメーター用のカウンターが、出来ました。
パターン面 30㎜*34㎜の大きさです。
基板上面 いつものとおり部品はなるべく省略 ５Ｖ入力すれば7805も不要です。
PIC16F54 アノードコモン７セグＬＥＤ ｸﾛｯｸ４ＭＨｚ
アセンブラーリストです。
下はＵＨＦ用のデップメーターです。
コイルはＵ字形です。真ん中はＲＦＣです。300から500ＭＨｚ位まで発信しています。
結構発信出力は強く100メーター位離れてもハンディトランシーバーで受信できます。
★ 御注意 ★
当サイトの回路図等は一部省略して記載してありますので実際作る場合はご注意ください。
１ 電源回路にノイズ防止用のコンデンサーを入れる必要があります。
例えば５Ｖとグランド間に10μＦ以上の電解コンデンサーを入れる。
特にＣＮＣコントロールの場合は各ＩＣ・各電源ごとに1000μＦ以上入れてください。
ＰＩＣの５Ｖ－ＧＮＤ間に0.2μＦ位のコンデンサーを入れる。
7805等の定電圧ＩＣの場合は足のそばに入れてください。
２ ＰＩＣ－７ＳＥＧ の接続ですが、回路図ではほとんどの場合RB0-A,RB1-B........としてあります。
しかしアセンブラーリストを見て頂くと分かるように基板パターンの関係で入れ替えてあります。
; ADBECGF
RETLW B'10000010' ;0
RETLW B'11101011' ;1
RETLW B'10000101' ;2
以下省略
本来では"_GFEDCBA"でないと回路図と合いません。数字の表示が崩れてしまいます。
回路図とあわせる為には下の10000010等と合わせリストの修正をお願いします。
又は回路をリストに合わせてください。
３ RISET ピンの取り扱いはＲＩＳＥＴ必須のＰＩＣの場合は電源に繋いでください。
４ ｸﾛｯｸが3本足セラロックの場合は真ん中のピンはＧＮＤに落としてください。
クリスタルの場合は各端子から15ＰＦのＣでＧＮＤに落としてください。
５ 規格をOVERして使っている場合もあります。各自の責任でお願いします。
６ 私は使うよりも作ること自体が趣味で作品を使い込んでありません。
バグ等が残っている場合があります。
ご連絡いただければ出来る限り修正します。
７ リストを営利目的で使うことはお断りします。
８ 不具合や損害が発生しても責任は負いかねます。
９ 皆で電子工作を楽しみましょう！！！
2009/10/2
アルミ板を折り曲げて自作ケースに組み込みました。
40*50*100ｍｍ です。手にすっぽり入ります。
2ターンのコイルを付けて最高周波数156.1MHｚ 発信中
デジタル表示のデップメーターはダイヤルメモリも不要で使いやすいです。
コイルは適当に巻いてセットするだけです。
同じコイルで30.42Mhz発信、表示です。5倍くらいのカバー率です。
3から4個のコイルで全バンド使えます。
自動バンド表示切換えもうまくいって桁が切り替わっています。
内部の様子 これ以上小さくはならないと思います。
電源は9V100ｍA
発信周波数によって発信レベルが結構変動します。
ボリュームの調整が必要です。
自動レンジ切替ASMアセンブラーリスト PIC16F54 4桁 ダイナミック表示 一番左の桁が 100MHｚ、10MHｚ、1MHｚ と 自動で切り替わります。
現在の表示バンドの状況はコイル等より自分で判断してください。
小数点の表示は省略してあります。（LED表示機に小数点が無い）
